$regfile = "m328pdef.dat"
$crystal = 16000000
$hwstack = 48
$swstack = 48
$framesize = 64

$sim

' **** размещение и чтение из оператора DATA констант, переменных и адресов процедур (меток) ***

dim mystring as string * 4
dim s as string * 4
dim w as word
dim w2 as word
dim b as byte
dim b2 as byte
const myconst = 1

' --- чтение указателя на строку ---

mystring = "ABCD"

restore loc_1                                               ' указатель на начало таблицы данных
read b
read b
read w                                                      ' в w прочитаем адрес строки mystring

print hex(w)                                                ' напечатать

s = ""                                                      ' }
do                                                          ' }
   b = inp(w)                                               ' }
   s = s + chr(b)                                           ' }
   incr w                                                   ' }
loop until b = 0                                            ' } прочитать строку в s по адресу w

print s

' --- чтение адреса процедуры и ее выполнение ---

read dataptr                                                ' загрузить в указатель DATA R8,9 адрес процедуры foo
!movw r30,r8                                                ' R8,9 -> R30,31 (адрес перехода)
!icall                                                      ' вызвать процедуру foo по адресу в R30,31
print "done"

restore loc_2                                               ' если после READ были операции, то указатель чтения R8, 9 возможно испорчен. обновить.
read dataptr                                                ' загрузить в указатель DATA R8,9 адрес процедуры foo2
!movw r30,r8                                                ' R8,9 -> R30,31 (адрес перехода)
!icall                                                      ' вызвать процедуру foo2 по адресу в R30,31
print "done 2"

' ---- альтернативный способ --------------

w = loadlabel(foo3)                                         ' получить адрес процедуры foo3 в переменную w
shift w , right                                             ' чтобы получить адрес, надо поделить пополам
print "proc foo3 ptr = " ; hex(w)

restore loc_3                                               ' переместить указатель DATA в место, где хранится указатель на w
read w2                                                     ' прочитать его в w2
b = inp(w2)                                                 ' и получить по указателю значение w
incr w2
b2 = inp(w2)
print "proc from data = " ; hex(b2) ; hex(b)
!LDS R30,{b}                                                ' }
!LDS R31,{b2}                                               ' } b,b2 -> R30,31 (адрес перехода)
!icall                                                      ' вызвать процедуру foo3 по адресу в R30,31
print "done 3"

' --- цепочечные данные --------------

restore loc_4

read b                                                      ' }
read b                                                      ' } прочитать пару dummy-значений
read w                                                      ' прочитать адрес следующей цепочки
print hex(w)

!lds R8, {w}                                                ' }
!LDS R9, {w + 1}                                            ' } установить указатель DATA на следующую метку

while w <> 0
   read b                                                   ' }
   read b                                                   ' } прочитать пару dummy-значений
   read w                                                   ' прочитать адрес следующей цепочки
   print hex(w)
wend

end

' --- процедуры ------------------------------------

foo:
   print "foo"
return

foo2:
   print "foo 2"
return

foo3:
   print "foo 3"
return

' --- данные -----------------------------------
loc_1:
data myconst , 1 , varptr(mystring)
adr foo                                                     ' ссылка на процедуру в DATA должна быть выровнена по СЛОВУ (четное число байт)!!!
                                                            ' в противном случае нужно поставить метку и сделать restore метка
loc_2:
adr foo2                                                    ' ссылка на процедуру в DATA должна быть выровнена по СЛОВУ (четное число байт)!!!
                                                            ' в противном случае нужно поставить метку и сделать restore метка
loc_3:
data varptr(w)

loc_4:
data 1 , 2                                                  ' какие-то данные
adr2 loc_5                                                  ' адрес следующих данных или 0, если конец цепочки

data 1 , 2 , 3 , 4 , 5 , 6                                  ' какие-то совсем другие данные

loc_5:                                                      ' следующая цепочка:
data 7 , 8 , 0%                                             ' какие-то данные и 0 (слово) = конец цепочки